sqlserver字符串多行合并為一行

--創建測試表
CREATE TABLE [dbo].[TestRows2Columns](
    [Id] [int] IDENTITY(1,1) NOT NULL,
    [UserName] [nvarchar](50) NULL,
    [Subject] [nvarchar](50) NULL,
    [Source] [numeric](18,0) NULL
)
GO

--插入測試數據
INSERT INTO [TestRows2Columns] ([UserName],[Subject],[Source]) 
    SELECT N'張三',N'語文',60  UNION ALL
    SELECT N'李四',N'數學',70  UNION ALL
    SELECT N'王五',N'英語',80  UNION ALL
    SELECT N'王五',N'數學',75  UNION ALL
    SELECT N'王五',N'語文',57  UNION ALL
    SELECT N'李四',N'語文',80  UNION ALL
    SELECT N'張三',N'英語',100
GO

SELECT * FROM [TestRows2Columns]




--1 通過 select 累加
DECLARE @sql_col VARCHAR(8000)
SELECT @sql_col = ISNULL(@sql_col + ',','') + QUOTENAME([Subject]) FROM TestRows2Columns 
GROUP BY [Subject]

SELECT @sql_col




--2 通過 FOR xml path('') 合并字符串記錄
SELECT 
    STUFF(
        (SELECT '#' + Subject
         FROM TestRows2Columns
         WHERE UserName = '王五'
         FOR xml path('')
        ),1,1,''
        )
  
 
--3 分組合并字符串記錄
SELECT
    UserName,
    Subject = (
               STUFF(
                    (SELECT '#' + Subject
                     FROM TestRows2Columns
                     WHERE UserName = A.UserName
                     FOR xml path('')
                    ),1,1,''
                    )
                 )
FROM TestRows2Columns A
GROUP by UserName

?